The Nordhagen

While performing some refactorings to LazyFallback, I came across a small gotcha with the sequence of the drag and drop implementation in Adobe AIR. It seems that dropping files will trigger a NativeDragEvent.NATIVE_DRAG_EXIT just before the NativeDragEvent.NATIVE_DRAG_DROP fires. This might not be a problem if all you use the NATIVE_DRAG_EXIT event for is to update some visuals. I my case however, I was also clearing the file list to be processed, which lead me to spot the problem.

Here’s an example class:

public class DropTest {
   private var fileQue:Array;
   private var dropWell:Sprite;

   public function DropTest () {
      dropWell.addEventListener( NativeDragEvent.NATIVE_DRAG_ENTER, dragEnterhandler );
      dropWell.addEventListener( NativeDragEvent.NATIVE_DRAG_DROP, dropHandler );
      dropWell.addEventListener( NativeDragEvent.NATIVE_DRAG_EXIT, dragExitHandler );
   }

   private function dragEnterhandler ( event:NativeDragEvent ):void {
      var files:Array = event.clipboard.getData( ClipboardFormats.FILE_LIST_FORMAT ) as Array;
      if (files && files.length) queFiles( files );
      else queFiles( null );
   }

   private function queFiles ( files:Array ):void {
      fileQue = files;
      if (files) {
         NativeDragManager.acceptDragDrop(dropWell);
         // Update visuals
      }
      else {
         // Update visuals
      }
   }
   private function dragExitHandler ( event:NativeDragEvent ):void {
      // This event handler will be called before dropHandler when dropping files
      queFiles( null );
   }

   private function dropHandler ( event:NativeDragEvent ):void {
      for each (var file:File in fileQue) {
         processFile( file ); // Fails because dragExitHandler has nulled fileQue
      }
   }
}

My suggestion for a solution to this is that you assign responsibilities for the event handlers as follows:

• NativeDragEvent.NATIVE_DRAG_ENTER: Validate files and update visuals
• NativeDragEvent.NATIVE_DRAG_DROP: Que files and start processsing
• NativeDragEvent.NATIVE_DRAG_EXIT: Update visuals